home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 26 / Cream of the Crop 26.iso / os2 / octa209s.zip / octave-2.09 / libcruft / lapack / zungql.f < prev    next >
Text File  |  1997-06-25  |  6KB  |  206 lines
  1.       SUBROUTINE ZUNGQL( M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
  2. *
  3. *  -- LAPACK routine (version 2.0) --
  4. *     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
  5. *     Courant Institute, Argonne National Lab, and Rice University
  6. *     September 30, 1994
  7. *
  8. *     .. Scalar Arguments ..
  9.       INTEGER            INFO, K, LDA, LWORK, M, N
  10. *     ..
  11. *     .. Array Arguments ..
  12.       COMPLEX*16         A( LDA, * ), TAU( * ), WORK( LWORK )
  13. *     ..
  14. *
  15. *  Purpose
  16. *  =======
  17. *
  18. *  ZUNGQL generates an M-by-N complex matrix Q with orthonormal columns,
  19. *  which is defined as the last N columns of a product of K elementary
  20. *  reflectors of order M
  21. *
  22. *        Q  =  H(k) . . . H(2) H(1)
  23. *
  24. *  as returned by ZGEQLF.
  25. *
  26. *  Arguments
  27. *  =========
  28. *
  29. *  M       (input) INTEGER
  30. *          The number of rows of the matrix Q. M >= 0.
  31. *
  32. *  N       (input) INTEGER
  33. *          The number of columns of the matrix Q. M >= N >= 0.
  34. *
  35. *  K       (input) INTEGER
  36. *          The number of elementary reflectors whose product defines the
  37. *          matrix Q. N >= K >= 0.
  38. *
  39. *  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
  40. *          On entry, the (n-k+i)-th column must contain the vector which
  41. *          defines the elementary reflector H(i), for i = 1,2,...,k, as
  42. *          returned by ZGEQLF in the last k columns of its array
  43. *          argument A.
  44. *          On exit, the M-by-N matrix Q.
  45. *
  46. *  LDA     (input) INTEGER
  47. *          The first dimension of the array A. LDA >= max(1,M).
  48. *
  49. *  TAU     (input) COMPLEX*16 array, dimension (K)
  50. *          TAU(i) must contain the scalar factor of the elementary
  51. *          reflector H(i), as returned by ZGEQLF.
  52. *
  53. *  WORK    (workspace/output) COMPLEX*16 array, dimension (LWORK)
  54. *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
  55. *
  56. *  LWORK   (input) INTEGER
  57. *          The dimension of the array WORK. LWORK >= max(1,N).
  58. *          For optimum performance LWORK >= N*NB, where NB is the
  59. *          optimal blocksize.
  60. *
  61. *  INFO    (output) INTEGER
  62. *          = 0:  successful exit
  63. *          < 0:  if INFO = -i, the i-th argument has an illegal value
  64. *
  65. *  =====================================================================
  66. *
  67. *     .. Parameters ..
  68.       COMPLEX*16         ZERO
  69.       PARAMETER          ( ZERO = ( 0.0D+0, 0.0D+0 ) )
  70. *     ..
  71. *     .. Local Scalars ..
  72.       INTEGER            I, IB, IINFO, IWS, J, KK, L, LDWORK, NB, NBMIN,
  73.      $                   NX
  74. *     ..
  75. *     .. External Subroutines ..
  76.       EXTERNAL           XERBLA, ZLARFB, ZLARFT, ZUNG2L
  77. *     ..
  78. *     .. Intrinsic Functions ..
  79.       INTRINSIC          MAX, MIN
  80. *     ..
  81. *     .. External Functions ..
  82.       INTEGER            ILAENV
  83.       EXTERNAL           ILAENV
  84. *     ..
  85. *     .. Executable Statements ..
  86. *
  87. *     Test the input arguments
  88. *
  89.       INFO = 0
  90.       IF( M.LT.0 ) THEN
  91.          INFO = -1
  92.       ELSE IF( N.LT.0 .OR. N.GT.M ) THEN
  93.          INFO = -2
  94.       ELSE IF( K.LT.0 .OR. K.GT.N ) THEN
  95.          INFO = -3
  96.       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
  97.          INFO = -5
  98.       ELSE IF( LWORK.LT.MAX( 1, N ) ) THEN
  99.          INFO = -8
  100.       END IF
  101.       IF( INFO.NE.0 ) THEN
  102.          CALL XERBLA( 'ZUNGQL', -INFO )
  103.          RETURN
  104.       END IF
  105. *
  106. *     Quick return if possible
  107. *
  108.       IF( N.LE.0 ) THEN
  109.          WORK( 1 ) = 1
  110.          RETURN
  111.       END IF
  112. *
  113. *     Determine the block size.
  114. *
  115.       NB = ILAENV( 1, 'ZUNGQL', ' ', M, N, K, -1 )
  116.       NBMIN = 2
  117.       NX = 0
  118.       IWS = N
  119.       IF( NB.GT.1 .AND. NB.LT.K ) THEN
  120. *
  121. *        Determine when to cross over from blocked to unblocked code.
  122. *
  123.          NX = MAX( 0, ILAENV( 3, 'ZUNGQL', ' ', M, N, K, -1 ) )
  124.          IF( NX.LT.K ) THEN
  125. *
  126. *           Determine if workspace is large enough for blocked code.
  127. *
  128.             LDWORK = N
  129.             IWS = LDWORK*NB
  130.             IF( LWORK.LT.IWS ) THEN
  131. *
  132. *              Not enough workspace to use optimal NB:  reduce NB and
  133. *              determine the minimum value of NB.
  134. *
  135.                NB = LWORK / LDWORK
  136.                NBMIN = MAX( 2, ILAENV( 2, 'ZUNGQL', ' ', M, N, K, -1 ) )
  137.             END IF
  138.          END IF
  139.       END IF
  140. *
  141.       IF( NB.GE.NBMIN .AND. NB.LT.K .AND. NX.LT.K ) THEN
  142. *
  143. *        Use blocked code after the first block.
  144. *        The last kk columns are handled by the block method.
  145. *
  146.          KK = MIN( K, ( ( K-NX+NB-1 ) / NB )*NB )
  147. *
  148. *        Set A(m-kk+1:m,1:n-kk) to zero.
  149. *
  150.          DO 20 J = 1, N - KK
  151.             DO 10 I = M - KK + 1, M
  152.                A( I, J ) = ZERO
  153.    10       CONTINUE
  154.    20    CONTINUE
  155.       ELSE
  156.          KK = 0
  157.       END IF
  158. *
  159. *     Use unblocked code for the first or only block.
  160. *
  161.       CALL ZUNG2L( M-KK, N-KK, K-KK, A, LDA, TAU, WORK, IINFO )
  162. *
  163.       IF( KK.GT.0 ) THEN
  164. *
  165. *        Use blocked code
  166. *
  167.          DO 50 I = K - KK + 1, K, NB
  168.             IB = MIN( NB, K-I+1 )
  169.             IF( N-K+I.GT.1 ) THEN
  170. *
  171. *              Form the triangular factor of the block reflector
  172. *              H = H(i+ib-1) . . . H(i+1) H(i)
  173. *
  174.                CALL ZLARFT( 'Backward', 'Columnwise', M-K+I+IB-1, IB,
  175.      $                      A( 1, N-K+I ), LDA, TAU( I ), WORK, LDWORK )
  176. *
  177. *              Apply H to A(1:m-k+i+ib-1,1:n-k+i-1) from the left
  178. *
  179.                CALL ZLARFB( 'Left', 'No transpose', 'Backward',
  180.      $                      'Columnwise', M-K+I+IB-1, N-K+I-1, IB,
  181.      $                      A( 1, N-K+I ), LDA, WORK, LDWORK, A, LDA,
  182.      $                      WORK( IB+1 ), LDWORK )
  183.             END IF
  184. *
  185. *           Apply H to rows 1:m-k+i+ib-1 of current block
  186. *
  187.             CALL ZUNG2L( M-K+I+IB-1, IB, IB, A( 1, N-K+I ), LDA,
  188.      $                   TAU( I ), WORK, IINFO )
  189. *
  190. *           Set rows m-k+i+ib:m of current block to zero
  191. *
  192.             DO 40 J = N - K + I, N - K + I + IB - 1
  193.                DO 30 L = M - K + I + IB, M
  194.                   A( L, J ) = ZERO
  195.    30          CONTINUE
  196.    40       CONTINUE
  197.    50    CONTINUE
  198.       END IF
  199. *
  200.       WORK( 1 ) = IWS
  201.       RETURN
  202. *
  203. *     End of ZUNGQL
  204. *
  205.       END
  206.